Return to bcopy.S CVS log

Up to [local] / sys / lib / libkern / arch / mips64

Annotation of sys/lib/libkern/arch/mips64/bcopy.S, Revision 1.1.1.1

1.1       nbrk        1: /*     $OpenBSD: bcopy.S,v 1.4 2004/10/08 14:42:09 pefo Exp $  */
                      2: /*-
                      3:  * Copyright (c) 1991, 1993
                      4:  *      The Regents of the University of California.  All rights reserved.
                      5:  *
                      6:  * This code is derived from software contributed to Berkeley by
                      7:  * Ralph Campbell.
                      8:  *
                      9:  * Redistribution and use in source and binary forms, with or without
                     10:  * modification, are permitted provided that the following conditions
                     11:  * are met:
                     12:  * 1. Redistributions of source code must retain the above copyright
                     13:  *    notice, this list of conditions and the following disclaimer.
                     14:  * 2. Redistributions in binary form must reproduce the above copyright
                     15:  *    notice, this list of conditions and the following disclaimer in the
                     16:  *    documentation and/or other materials provided with the distribution.
                     17:  * 3. Neither the name of the University nor the names of its contributors
                     18:  *    may be used to endorse or promote products derived from this software
                     19:  *    without specific prior written permission.
                     20:  *
                     21:  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
                     22:  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
                     23:  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
                     24:  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
                     25:  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
                     26:  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
                     27:  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
                     28:  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
                     29:  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
                     30:  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
                     31:  * SUCH DAMAGE.
                     32:  */
                     33:
                     34: #include "DEFS.h"
                     35:
                     36:
                     37: /*
                     38:  * memcpy(to, from, len)
                     39:  * {ov}bcopy(from, to, len)
                     40:  */
                     41: LEAF(memcpy, 0)
                     42:        .set    noreorder
                     43:        move    v0, a0                  # swap from and to
                     44:        move    a0, a1
                     45:        move    a1, v0
                     46: ALEAF(bcopy)
                     47: ALEAF(ovbcopy)
                     48:        .set    noreorder
                     49:        PTR_ADDU t0, a0, a2             # t0 = end of s1 region
                     50:        sltu    t1, a1, t0
                     51:        sltu    t2, a0, a1
                     52:        and     t1, t1, t2              # t1 = true if from < to < (from+len)
                     53:        beq     t1, zero, forward       # non overlapping, do forward copy
                     54:        slt     t2, a2, 12              # check for small copy
                     55:
                     56:        ble     a2, zero, 2f
                     57:        PTR_ADDU t1, a1, a2             # t1 = end of to region
                     58: 1:
                     59:        lb      v1, -1(t0)              # copy bytes backwards,
                     60:        PTR_SUBU t0, t0, 1              #   doesnt happen often so do slow way
                     61:        PTR_SUBU t1, t1, 1
                     62:        bne     t0, a0, 1b
                     63:        sb      v1, 0(t1)
                     64: 2:
                     65:        j       ra
                     66:        nop
                     67: forward:
                     68:        bne     t2, zero, smallcpy      # do a small bcopy
                     69:        xor     v1, a0, a1              # compare low two bits of addresses
                     70:        and     v1, v1, 3
                     71:        PTR_SUBU a3, zero, a1           # compute # bytes to word align address
                     72:        beq     v1, zero, aligned       # addresses can be word aligned
                     73:        and     a3, a3, 3
                     74:
                     75:        beq     a3, zero, 1f
                     76:        PTR_SUBU a2, a2, a3             # subtract from remaining count
                     77:        LWHI    v1, 0(a0)               # get next 4 bytes (unaligned)
                     78:        LWLO    v1, 3(a0)
                     79:        PTR_ADDU a0, a0, a3
                     80:        SWHI    v1, 0(a1)               # store 1, 2, or 3 bytes to align a1
                     81:        PTR_ADDU a1, a1, a3
                     82: 1:
                     83:        and     v1, a2, 3               # compute number of words left
                     84:        PTR_SUBU a3, a2, v1
                     85:        move    a2, v1
                     86:        PTR_ADDU a3, a3, a0             # compute ending address
                     87: 2:
                     88:        LWHI    v1, 0(a0)               # copy words a0 unaligned, a1 aligned
                     89:        LWLO    v1, 3(a0)
                     90:        PTR_ADDU a0, a0, 4
                     91:        sw      v1, 0(a1)
                     92:        PTR_ADDU a1, a1, 4
                     93:        bne     a0, a3, 2b
                     94:        nop                             # We have to do this mmu-bug.
                     95:        b       smallcpy
                     96:        nop
                     97: aligned:
                     98:        beq     a3, zero, 1f
                     99:        PTR_SUBU a2, a2, a3             # subtract from remaining count
                    100:        LWHI    v1, 0(a0)               # copy 1, 2, or 3 bytes to align
                    101:        PTR_ADDU a0, a0, a3
                    102:        SWHI    v1, 0(a1)
                    103:        PTR_ADDU a1, a1, a3
                    104: 1:
                    105:        and     v1, a2, 3               # compute number of whole words left
                    106:        PTR_SUBU a3, a2, v1
                    107:        move    a2, v1
                    108:        PTR_ADDU a3, a3, a0             # compute ending address
                    109: 2:
                    110:        lw      v1, 0(a0)               # copy words
                    111:        PTR_ADDU a0, a0, 4
                    112:        sw      v1, 0(a1)
                    113:        bne     a0, a3, 2b
                    114:        PTR_ADDU a1, a1, 4
                    115: smallcpy:
                    116:        ble     a2, zero, 2f
                    117:        PTR_ADDU a3, a2, a0             # compute ending address
                    118: 1:
                    119:        lbu     v1, 0(a0)               # copy bytes
                    120:        PTR_ADDU a0, a0, 1
                    121:        sb      v1, 0(a1)
                    122:        bne     a0, a3, 1b
                    123:        PTR_ADDU a1, a1, 1      # MMU BUG ? can not do -1(a1) at 0x80000000!!
                    124: 2:
                    125:        j       ra
                    126:        nop
                    127: END(memcpy)