Annotation of sys/lib/libkern/arch/m68k/memcmp.S, Revision 1.1.1.1
1.1 nbrk 1: /* $OpenBSD: memcmp.S,v 1.2 2003/06/02 23:28:08 millert Exp $ */
2:
3: /*-
4: * Copyright (c) 1990 The Regents of the University of California.
5: * All rights reserved.
6: *
7: * This code is derived from software contributed to Berkeley by
8: * the Systems Programming Group of the University of Utah Computer
9: * Science Department.
10: *
11: * Redistribution and use in source and binary forms, with or without
12: * modification, are permitted provided that the following conditions
13: * are met:
14: * 1. Redistributions of source code must retain the above copyright
15: * notice, this list of conditions and the following disclaimer.
16: * 2. Redistributions in binary form must reproduce the above copyright
17: * notice, this list of conditions and the following disclaimer in the
18: * documentation and/or other materials provided with the distribution.
19: * 3. Neither the name of the University nor the names of its contributors
20: * may be used to endorse or promote products derived from this software
21: * without specific prior written permission.
22: *
23: * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
24: * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
25: * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
26: * ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
27: * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
28: * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
29: * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
30: * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
31: * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
32: * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
33: * SUCH DAMAGE.
34: */
35:
36: #include "DEFS.h"
37:
38: #if defined(LIBC_SCCS)
39: .text
40: .asciz "$OpenBSD: memcmp.S,v 1.2 2003/06/02 23:28:08 millert Exp $"
41: #endif /* LIBC_SCCS */
42:
43: /* memcmp(s1, s2, n) */
44:
45: /*
46: * This is probably not the best we can do, but it is still 2-10 times
47: * faster than the C version in the portable gen directory.
48: *
49: * Things that might help:
50: * - longword align when possible (only on the 68020)
51: * - use nested DBcc instructions or use one and limit size to 64K
52: */
53: ENTRY(memcmp)
54: movl sp@(4),a0 | string 1
55: movl sp@(8),a1 | string 2
56: movl sp@(12),d0 | length
57: beq bcdone | if zero, nothing to do
58: movl a0,d1
59: btst #0,d1 | string 1 address odd?
60: beq bceven | no, skip alignment
61: cmpmb a0@+,a1@+ | yes, compare a byte
62: bne bcnoteq | not equal, return non-zero
63: subql #1,d0 | adjust count
64: beq bcdone | count 0, reutrn zero
65: bceven:
66: movl a1,d1
67: btst #0,d1 | string 2 address odd?
68: bne bcbloop | yes, no hope for alignment, compare bytes
69: movl d0,d1 | no, both even
70: lsrl #2,d1 | convert count to longword count
71: beq bcbloop | count 0, skip longword loop
72: bclloop:
73: cmpml a0@+,a1@+ | compare a longword
74: bne bcnoteql | not equal, return non-zero
75: subql #1,d1 | adjust count
76: bne bclloop | still more, keep comparing
77: andl #3,d0 | what remains
78: beq bcdone | nothing, all done
79: bcbloop:
80: cmpmb a0@+,a1@+ | compare a byte
81: bne bcnoteq | not equal, return non-zero
82: subql #1,d0 | adjust count
83: bne bcbloop | still more, keep going
84: rts
85: bcnoteql:
86: subql #4,a0
87: subql #4,a1
88: movl #4,d0
89: jra bcbloop
90: bcnoteq:
91: clrl d0
92: clrl d1
93: movb a0@-,d0
94: movb a1@-,d1
95: subl d1,d0
96: bcdone:
97: rts
CVSweb