Annotation of sys/lib/libkern/arch/m68k/bcmp.S, Revision 1.1.1.1
1.1 nbrk 1: /* $OpenBSD: bcmp.S,v 1.3 2003/06/02 23:28:08 millert Exp $ */
2:
3: /*-
4: * Copyright (c) 1990 The Regents of the University of California.
5: * All rights reserved.
6: *
7: * This code is derived from software contributed to Berkeley by
8: * the Systems Programming Group of the University of Utah Computer
9: * Science Department.
10: *
11: * Redistribution and use in source and binary forms, with or without
12: * modification, are permitted provided that the following conditions
13: * are met:
14: * 1. Redistributions of source code must retain the above copyright
15: * notice, this list of conditions and the following disclaimer.
16: * 2. Redistributions in binary form must reproduce the above copyright
17: * notice, this list of conditions and the following disclaimer in the
18: * documentation and/or other materials provided with the distribution.
19: * 3. Neither the name of the University nor the names of its contributors
20: * may be used to endorse or promote products derived from this software
21: * without specific prior written permission.
22: *
23: * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
24: * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
25: * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
26: * ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
27: * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
28: * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
29: * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
30: * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
31: * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
32: * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
33: * SUCH DAMAGE.
34: */
35:
36: #if defined(LIBC_SCCS) && !defined(lint)
37: .text
38: /*.asciz "from: @(#)bcmp.s 5.1 (Berkeley) 5/12/90"*/
39: .asciz "$OpenBSD: bcmp.S,v 1.3 2003/06/02 23:28:08 millert Exp $"
40: #endif /* LIBC_SCCS and not lint */
41:
42: /* bcmp(s1, s2, n) */
43:
44: #include "DEFS.h"
45:
46: /*
47: * This is probably not the best we can do, but it is still 2-10 times
48: * faster than the C version in the portable gen directory.
49: *
50: * Things that might help:
51: * - longword align when possible (only on the 68020)
52: * - use nested DBcc instructions or use one and limit size to 64K
53: */
54: ENTRY(bcmp)
55: movl sp@(4),a0 | string 1
56: movl sp@(8),a1 | string 2
57: movl sp@(12),d0 | length
58: beq bcdone | if zero, nothing to do
59: movl a0,d1
60: btst #0,d1 | string 1 address odd?
61: beq bceven | no, skip alignment
62: cmpmb a0@+,a1@+ | yes, compare a byte
63: bne bcnoteq | not equal, return non-zero
64: subql #1,d0 | adjust count
65: beq bcdone | count 0, reutrn zero
66: bceven:
67: movl a1,d1
68: btst #0,d1 | string 2 address odd?
69: bne bcbloop | yes, no hope for alignment, compare bytes
70: movl d0,d1 | no, both even
71: lsrl #2,d1 | convert count to longword count
72: beq bcbloop | count 0, skip longword loop
73: bclloop:
74: cmpml a0@+,a1@+ | compare a longword
75: bne bcnoteq | not equal, return non-zero
76: subql #1,d1 | adjust count
77: bne bclloop | still more, keep comparing
78: andl #3,d0 | what remains
79: beq bcdone | nothing, all done
80: bcbloop:
81: cmpmb a0@+,a1@+ | compare a byte
82: bne bcnoteq | not equal, return non-zero
83: subql #1,d0 | adjust count
84: bne bcbloop | still more, keep going
85: rts
86: bcnoteq:
87: moveq #1,d0
88: bcdone:
89: rts
CVSweb